[решено] Удаление элементов TreeView

[gregaz]

Создание 1000 элементов в TreeView с помощью _GUICtrlTreeView_Add
занимает порядка 2-х сек
Очистка же дерева с помощью _GUICtrlTreeView_DeleteAll
занимает порядка 15 сек

Как быстро обновить дерево ?

[Busla]

Сейчас скажут, что я предлагаю злостный оффтопик, но AutoIt - скриптовая платформа для автоматизации несложных задач, а не универсальный язык для построения GUI-приложений с тысячами элементов интерфейса. Начинайте потихоньку осваивать, например, C#

[Creat0R]

Как быстро обновить дерево ? »
Нужно "сообщить" элементу что выполняется обновление:

#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
;

GUICreate("TreeView Delete All", 400, 300)
GUISetState()

$hTreeView = GUICtrlCreateTreeView(10, 5, 380, 250, _
BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)

$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, "shell32.dll", 110)
_GUIImageList_AddIcon($hImage, "shell32.dll", 131)
_GUIImageList_AddIcon($hImage, "shell32.dll", 165)
_GUIImageList_AddIcon($hImage, "shell32.dll", 168)
_GUIImageList_AddIcon($hImage, "shell32.dll", 137)
_GUIImageList_AddIcon($hImage, "shell32.dll", 146)
_GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

$iTimer = TimerInit()

_GUICtrlTreeView_BeginUpdate($hTreeView)

For $x = 1 To 1000
$iImage = Random(0, 5, 1)
$hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
Next

_GUICtrlTreeView_EndUpdate($hTreeView)

MsgBox(4160, "Information", "Create (1000 items) duration: " & Round(TimerDiff($iTimer)/1000, 1) & " sec.")

$DeleteAll_Button = GUICtrlCreateButton("Delete All", 20, 270, 70, 20)

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $DeleteAll_Button
$iTimer = TimerInit()

_GUICtrlTreeView_BeginUpdate($hTreeView)
_GUICtrlTreeView_DeleteAll($hTreeView)
_GUICtrlTreeView_EndUpdate($hTreeView)

MsgBox(4160, "Information", "Delete All (1000 items) duration: " & Round(TimerDiff($iTimer)/1000, 1) & " sec.")
EndSwitch
WEnd

AutoIt - скриптовая платформа для автоматизации несложных задач, а не универсальный язык для построения GUI-приложений с тысячами элементов интерфейса »
Может и не универсальный, но вполне пригоден для этой задачи. А по-поводу автоматизации несложных задач... это ещё очень даже спорно, ни один скриптовый язык не собирает в себе те возможности что есть у AutoIt'а, на нём всё же можно решать довольно сложные задачи.

[gregaz]

Creat0R, Спасибо
Даже не подумал обьявить обновление при удалении.
И в справке вроде бы молчок
Теперь все ОК

[gregaz]

Сейчас скажут, что я предлагаю злостный оффтопик, но AutoIt - скриптовая платформа для автоматизации несложных задач, а не универсальный язык для построения GUI-приложений с тысячами элементов интерфейса. »

Не согласен
AutoIt вначале создавался для автоматизации несложных задач.
Теперь же он способен решать достаточно серьезные задачи и поэтому его популярность растет.